configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl Must reset CDPATH so that bash's cd does not print to stdout
   4 dnl CDPATH=
   5
   6 AC_INIT(src/ctrec.cpp)
   7 AM_INIT_AUTOMAKE(ctsim,1.9.5)
   8 AM_CONFIG_HEADER(config.h)
   9
  10 dnl Checks for programs.
  11 AC_PROG_AWK
  12 AC_PROG_INSTALL
  13 AC_PROG_MAKE_SET
  14 AC_PROG_RANLIB
  15 AC_PROG_CC
  16 AC_PROG_CXX
  17
  18
  19 dnl AC_MSG_CHECKING([that the compiler works])
  20 dnl AC_TRY_RUN([ main(int ac, char **av) { return 0; } ],     AC_MSG_RESULT(yes),     AC_MSG_RESULT(no)     AC_MSG_ERROR(Could not compile and run even a trivial ANSI C program - check CC.),     AC_MSG_ERROR(Could not compile and run even a trivial ANSI C program - check CC.))
  21
  22 dnl Check for C operation
  23 AC_CANONICAL_HOST
  24 AC_C_INLINE
  25 AC_CHECK_SIZEOF(short, 2)
  26 AC_CHECK_SIZEOF(int, 4)
  27 AC_CHECK_SIZEOF(long, 4)
  28 AC_CHECK_SIZEOF(float, 4)
  29 AC_CHECK_SIZEOF(double, 8)
  30
  31 dnl ---------------------------------------------------------------------------
  32 dnl a slightly better AC_C_BIGENDIAN macro which allows cross-compiling
  33 dnl from wxGTK (www.wxwindows.org) - LGPL license
  34 dnl ---------------------------------------------------------------------------
  35
  36 AC_DEFUN(WX_C_BIGENDIAN,
  37 [AC_CACHE_CHECK(whether byte ordering is bigendian, ac_cv_c_bigendian,
  38 [ac_cv_c_bigendian=unknown
  39 # See if sys/param.h defines the BYTE_ORDER macro.
  40 AC_TRY_COMPILE([#include <sys/types.h>
  41 #include <sys/param.h>], [
  42 #if !BYTE_ORDER || !BIG_ENDIAN || !LITTLE_ENDIAN
  43  bogus endian macros
  44 #endif], [# It does; now see whether it defined to BIG_ENDIAN or not.
  45 AC_TRY_COMPILE([#include <sys/types.h>
  46 #include <sys/param.h>], [
  47 #if BYTE_ORDER != BIG_ENDIAN
  48  not big endian
  49 #endif], ac_cv_c_bigendian=yes, ac_cv_c_bigendian=no)])
  50 if test $ac_cv_c_bigendian = unknown; then
  51 AC_TRY_RUN([main () {
  52   /* Are we little or big endian?  From Harbison&Steele.  */
  53   union
  54   {
  55     long l;
  56     char c[sizeof (long)];
  57   } u;
  58   u.l = 1;
  59   exit (u.c[sizeof (long) - 1] == 1);
  60 }], ac_cv_c_bigendian=no, ac_cv_c_bigendian=yes, ac_cv_c_bigendian=unknown)
  61 fi])
  62 if test $ac_cv_c_bigendian = unknown; then
  63   AC_MSG_WARN([Assuming little-endian target machine - this may be overriden by adding the line "ac_cv_c_bigendian=${ac_cv_c_bigendian='yes'}"
  64 to config.cache file])
  65 fi
  66 if test $ac_cv_c_bigendian = yes; then
  67   AC_DEFINE(WORDS_BIGENDIAN)
  68 fi
  69 ])
  70
  71 WX_C_BIGENDIAN
  72
  73
  74 dnl Checks for libraries.
  75 AC_CHECK_LIB(z, main, [ zlib="true" ], [ zlib="false" ;  AC_MSG_WARN([zlib missing. Will need zlib for PNG support])])
  76 AC_CHECK_LIB(m, main)
  77 AC_CHECK_LIB(curses, main, [curses=true], [curses=false])
  78 AC_CHECK_LIB(ncurses, main, [ncurses=true], [ncurses=false])
  79 AC_CHECK_LIB(g2, main, [g2=true], [g2=false])
  80 AC_CHECK_LIB(wx_gtk, main, [wxwin=true; wx_gtk=true; AC_DEFINE(HAVE_WXWINDOWS)], [wxwin=false])
  81 AC_CHECK_LIB(wx_msw, main, [wxwin=true; wx_msw=true; AC_DEFINE(HAVE_WXWINDOWS)], [wxwin=false])
  82
  83 if test "$zlib" = "true" ; then
  84   AC_CHECK_LIB(png, main, [png=true ; AC_DEFINE(HAVE_PNG)], [png=false])
  85 fi
  86
  87 dnl Checks for header files.
  88 AC_HEADER_STDC
  89 AC_CHECK_HEADERS(fcntl.h unistd.h getopt.h sys/fcntl.h setjmp.h stdarg.h stddef.h sys/types.h sys/stat.h string.h ctype.h math.h stdio.h netinet/in.h inttypes.h sys/param.h stdint.h stdlib.h g2.h)
  90
  91 dnl Checks for typedefs, structures, and compiler characteristics.
  92 AC_C_CONST
  93 AC_TYPE_OFF_T
  94 AC_TYPE_SIZE_T
  95 AC_STRUCT_TM
  96
  97 dnl Checks for library functions.
  98 AC_FUNC_VPRINTF
  99 AC_CHECK_FUNCS(strtod strtol snprintf htonl)
 100 AC_CHECK_FUNC(basename)
 101 AC_CHECK_FUNC(setjmp)
 102 if test "${OSTYPE}" = "cygwin" ; then
 103   getopt_long=false
 104 else
 105   AC_CHECK_FUNC(getopt_long, [ getopt_long=true ], [ getopt_long=false ])
 106 fi
 107 if test "${getopt_long}" = "false" ; then
 108   my_includes="$myincludes -I../getopt"
 109   AC_DEFINE(HAVE_GETOPT_LONG)
 110   ctlibs_base="$ctlibs_base -lgetopt"
 111   LDFLAGS="$LDFLAGS -L../getopt"
 112   AM_CONDITIONAL(INCLUDED_GETOPT_LONG, test 1==1)
 113 fi
 114
 115
 116 AC_ADD_GCC_CFLAGS([-Wall])
 117 AC_MSG_CHECKING(whether to enable verbose warnings)
 118 AC_ARG_ENABLE(verbose-warnings,
 119 [  --enable-verbose-warnings
 120                           Enable verbose compiler warnings.],
 121 [ case "$enableval" in
 122   yes)
 123     AC_MSG_RESULT(yes)
 124     AC_ADD_GCC_CFLAGS([-W])
 125     AC_ADD_GCC_CFLAGS([-Wshadow -Wpointer-arith -Wbad-function-cast])
 126     AC_ADD_GCC_CFLAGS([-Wcast-align -Wwrite-strings -Waggregate-return])
 127     AC_ADD_GCC_CFLAGS([-Wmissing-prototypes -Wstrict-prototypes])
 128     AC_ADD_GCC_CFLAGS([-pedantic])
 129     AC_ADD_GCC_CFLAGS([-Wredundant-decls])
 130
 131     ;;
 132   *)
 133     AC_MSG_RESULT(no)
 134     ;;
 135   esac ], AC_MSG_RESULT(no)
 136 )
 137
 138 dnl Check for debug mode
 139 AC_ARG_ENABLE(debug,
 140 [  --enable-debug          Turn on debugging],
 141 [case "${enableval}" in
 142   yes) debug=true
 143        CFLAGS="$CFLAGS -g"
 144        ;;
 145   no)  debug=false
 146        CFLAGS="$CFLAGS -O2"
 147        ;;
 148   *) AC_MSG_ERROR(bad value ${enableval} for --enable-debug)
 149        ;;
 150 esac],[debug=false])
 151 AM_CONDITIONAL(DEBUG, test "$debug" = "true")
 152
 153 dnl Set LAM path
 154 AC_ARG_WITH(lam,
 155 [  --with-lam[=PATH]       Set path of LAM MPI ],
 156 [    if test "$withval" != "no" ; then
 157          trylamdir=$withval
 158      fi ]
 159 )
 160
 161 if test "$withval" != "no" ; then
 162   if test "$prefix" != "NONE" ; then
 163      trylamdir="$trylamdir $prefix"
 164   fi
 165
 166   AC_MSG_CHECKING([for LAM MPI installation])
 167   for testlamdir in "." $trylamdir /usr/local /usr/local/lam /usr /usr/lam /opt /opt/lam ; do
 168     if test -x "$testlamdir/bin/hcc" ; then
 169       LDFLAGS="$LDFLAGS -L$testlamdir/lib"
 170       CFLAGS="$CFLAGS -I$testlamdir/include"
 171       lamdir="$testlamdir"
 172       AC_SUBST(lamdir)
 173       mpienable="true"
 174       AC_SUBST(mpienable)
 175       break
 176     fi
 177   done
 178   AC_MSG_RESULT($lamdir)
 179 else
 180   AC_MSG_RESULT([no])
 181 fi
 182
 183 AC_MSG_CHECKING([for web access])
 184 dnl Set cgi-bin directory
 185 AC_ARG_WITH(cgibin-dir, [  --with-cgibin-dir=PATH  Set path of CGI binaries directory ],
 186 [ cgibindir=$withval ; AC_SUBST(cgibindir) ] )
 187
 188 AC_ARG_WITH(cgibin-url, [  --with-cgibin-url=PATH  Set URL path of CGI binaries ],
 189 [ cgibinurl=$withval ; AC_SUBST(cgibinurl) ] )
 190
 191 AC_ARG_WITH(webdata-dir, [  --with-webdata-dir=PATH Set path of webdata],
 192 [ webdatadir=$withval ; AC_SUBST(webdatadir)  ] )
 193
 194 AC_ARG_WITH(webdata-url, [  --with-webdata-url=PATH Set URL path of webdata],
 195 [ webdataurl=$withval ; AC_SUBST(webdataurl) ] )
 196
 197 AC_ARG_WITH(html-dir, [  --with-html-dir=PATH    Set directory of html files],
 198 [ htmldir=$withval ; AC_SUBST(htmldir) ] )
 199
 200 if test -n "$cgibindir" -o -n "$cgibinurl" ; then
 201   cgiprograms="ctsim.cgi ctsim.conf"
 202   AC_SUBST(cgiprograms)
 203 fi
 204
 205 if test -n "$htmldir" ; then
 206   htmldata=simulate.html
 207   AC_SUBST(htmldata)
 208 fi
 209 AM_CONDITIONAL(USE_HTML, test -n "$htmldir")
 210
 211 if test -n "$cgibindir" -o -n "$cgibinurl" -o -n "$webdatadir" -o -n "$webdataurl" -o -n "$htmldir" ; then
 212   webenabled=true
 213   AC_SUBST(webenabled)
 214   AC_MSG_RESULT([yes])
 215   if test -z "$cgibindir" ; then
 216     AC_MSG_ERROR([--with-cgibin-dir not set for web access])
 217   elif test -z "$cgibinurl" ; then
 218     AC_MSG_ERROR([--with-cgibin-url not set for web access])
 219   elif test -z "$webdatadir" ; then
 220     AC_MSG_ERROR([--with-webdata-dir not set for web access])
 221   elif test -z "$webdataurl" ; then
 222     AC_MSG_ERROR([--with-webdata-url not set for web access])
 223   elif test -z "$htmldir" ; then
 224     AC_MSG_ERROR([--with-html-dir not set for web access])
 225   fi
 226 else
 227   AC_MSG_RESULT([no])
 228 fi
 229
 230 AM_CONDITIONAL(USE_LAM, test -n "$lamdir")
 231
 232 dnl Prepare to support X.  If the user gave the command-line option
 233 dnl --without-x, AC_PATH_XTRA will set no_x to "yes".  Otherwise, it will
 234 dnl add appropriate preprocessor flags to X_CFLAGS, and appropriate linker
 235 dnl flags to X_LIBS.  It also checks for system-specific X libraries, and
 236 dnl adds them to X_PRE_LIBS or X_EXTRA_LIBS, as appropriate.  (The former
 237 dnl is where "-lSM -lICE" goes, in X11R6.)  We define the X_TOOLKIT_LIBS
 238 dnl and X_BASIC_LIBS argument vectors ourselves, and if X is to be
 239 dnl supported, we'll concatenate the whole lot of these into a command line
 240 dnl for libtool.  See, e.g., the libplot_la_LIBADD line in
 241 dnl libplot/Makefile.am.
 242
 243 AC_PATH_XTRA
 244 AC_SUBST(X_CFLAGS)
 245 dnl Following five are concatenated together into a linker specification.
 246 AC_SUBST(X_LIBS)
 247 AC_SUBST(X_TOOLKIT_LIBS)
 248 AC_SUBST(X_PRE_LIBS)
 249 AC_SUBST(X_BASIC_LIBS)
 250 AC_SUBST(X_EXTRA_LIBS)
 251
 252 X_TOOLKIT_LIBS="-lXt"
 253 X_BASIC_LIBS="-lXext -lX11"
 254
 255 dnl Check whether libXt has thread support.  Some platforms may have
 256 dnl pthread support in libc, but no thread support in libXt/libX11.
 257 our_saved_LDFLAGS="$LDFLAGS"
 258 LDFLAGS="$X_LIBS $LDFLAGS"
 259 AC_CHECK_LIB(Xt, XtToolkitThreadInitialize, AC_DEFINE(X_THREAD_SUPPORT), , $X_PRE_LIBS $X_BASIC_LIBS $X_EXTRA_LIBS)
 260 LDFLAGS="$our_saved_LDFLAGS"
 261
 262 dnl Check in -lXext for double buffering extensions to X11, and check
 263 dnl whether appropriate header files are present.  (Some systems have one
 264 dnl but not the other.)
 265 our_saved_LDFLAGS="$LDFLAGS"
 266 LDFLAGS="$X_LIBS $LDFLAGS"
 267 AC_CHECK_LIB(Xext, XdbeQueryExtension, AC_DEFINE(HAVE_DBE_SUPPORT), , -lX11 "$X_EXTRA_LIBS")
 268 AC_CHECK_LIB(Xext, XmbufQueryExtension, AC_DEFINE(HAVE_MBX_SUPPORT), , -lX11 "$X_EXTRA_LIBS")
 269 LDFLAGS="$our_saved_LDFLAGS"
 270 our_saved_CPPFLAGS="$CPPFLAGS"
 271 CPPFLAGS="$X_CFLAGS $CPPFLAGS"
 272 AC_CHECK_HEADERS(X11/extensions/Xdbe.h X11/extensions/multibuf.h)
 273 CPPFLAGS="$our_saved_CPPFLAGS"
 274
 275 dnl Our Makefile.am files test the automake variable NO_X to determine
 276 dnl whether X should be supported.
 277 AM_CONDITIONAL(NO_X, test "x$no_x" = "xyes")
 278
 279 my_includes="$my_includes -I../include -I.."
 280 AC_SUBST(my_includes)
 281
 282 AC_MSG_CHECKING([interactive graphics])
 283 if test "$no_x" != "yes" ; then
 284   AC_DEFINE(HAVE_X11)
 285   AC_DEFINE(HAVE_SGP)
 286   AM_CONDITIONAL(HAVE_SGP, test 1==1)
 287   LDFLAGS="$LDFLAGS -L../libctgraphics -L/usr/X11R6/lib"
 288   ctlibs_graphics="$ctlibs_base -lctgraphics $X_BASIC_LIBS $X_TOOLKIT_LIBS"
 289   AC_MSG_RESULT(yes)
 290 else
 291   AC_MSG_RESULT(no)
 292 fi
 293
 294 if test "$png" = "true" ; then
 295   ctlibs_tools="$ctlibs_tools -lpng"
 296 fi
 297 if test "$zlib" = "true" ; then
 298   ctlibs_tools="$ctlibs_tools -lz"
 299 fi
 300 if test "$g2" = "true" ; then
 301   ctlibs_tools="$ctlibs_tools -lg2"
 302 fi
 303 if test "$wx_gtk" = "true" ; then
 304   ctlibs_tools="$ctlibs_tools -lwx_gtk"
 305 fi
 306
 307 dnl Setting projet libraries and includes
 308 LDFLAGS="$LDFLAGS -L../libctsupport -L../libctsim"
 309 ctlibs="$ctlibs_base -lctsim $ctlibs_graphics -lctsupport $ctlibs_tools"
 310 AC_SUBST(ctlibs)
 311
 312 if test -n "$lamdir" ; then
 313   lamprograms="ctrec-lam phm2if-lam phm2pj-lam"
 314   AC_SUBST(lamprograms)
 315 fi
 316
 317 AC_OUTPUT(Makefile src/Makefile libctgraphics/Makefile libctsupport/Makefile libctsim/Makefile Makefile man/Makefile cgi-bin/ctsim.cgi cgi-bin/Makefile html/simulate.html html/Makefile include/Makefile getopt/Makefile src/sample-ctrec.sh cgi-bin/ctsim.conf)