configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl Must reset CDPATH so that bash's cd does not print to stdout
   4 dnl CDPATH=
   5
   6 AC_INIT(src/ctsim.cpp)
   7 AM_INIT_AUTOMAKE(ctsim,2.0.0-b7)
   8 AM_CONFIG_HEADER(config.h)
   9
  10 dnl Checks for programs.
  11 AC_PROG_AWK
  12 AC_PROG_INSTALL
  13 AC_PROG_MAKE_SET
  14 AC_PROG_RANLIB
  15 AC_PROG_CC
  16 AC_PROG_CXX
  17 AC_PATH_PROG(wxconfig,wx-config)
  18
  19 dnl AC_MSG_CHECKING([that the compiler works])
  20 dnl AC_TRY_RUN([ main(int ac, char **av) { return 0; } ],     AC_MSG_RESULT(yes),     AC_MSG_RESULT(no)     AC_MSG_ERROR(Could not compile and run even a trivial ANSI C program - check CC.),     AC_MSG_ERROR(Could not compile and run even a trivial ANSI C program - check CC.))
  21
  22 dnl Check for C operation
  23 AC_CANONICAL_HOST
  24 AC_C_INLINE
  25 AC_CHECK_SIZEOF(short, 2)
  26 AC_CHECK_SIZEOF(int, 4)
  27 AC_CHECK_SIZEOF(long, 4)
  28 AC_CHECK_SIZEOF(float, 4)
  29 AC_CHECK_SIZEOF(double, 8)
  30
  31 dnl ---------------------------------------------------------------------------
  32 dnl a slightly better AC_C_BIGENDIAN macro which allows cross-compiling
  33 dnl from wxGTK (www.wxwindows.org) - LGPL license
  34 dnl ---------------------------------------------------------------------------
  35
  36 AC_DEFUN(WX_C_BIGENDIAN,
  37 [AC_CACHE_CHECK(whether byte ordering is bigendian, ac_cv_c_bigendian,
  38 [ac_cv_c_bigendian=unknown
  39 # See if sys/param.h defines the BYTE_ORDER macro.
  40 AC_TRY_COMPILE([#include <sys/types.h>
  41 #include <sys/param.h>], [
  42 #if !BYTE_ORDER || !BIG_ENDIAN || !LITTLE_ENDIAN
  43  bogus endian macros
  44 #endif], [# It does; now see whether it defined to BIG_ENDIAN or not.
  45 AC_TRY_COMPILE([#include <sys/types.h>
  46 #include <sys/param.h>], [
  47 #if BYTE_ORDER != BIG_ENDIAN
  48  not big endian
  49 #endif], ac_cv_c_bigendian=yes, ac_cv_c_bigendian=no)])
  50 if test $ac_cv_c_bigendian = unknown; then
  51 AC_TRY_RUN([main () {
  52   /* Are we little or big endian?  From Harbison&Steele.  */
  53   union
  54   {
  55     long l;
  56     char c[sizeof (long)];
  57   } u;
  58   u.l = 1;
  59   exit (u.c[sizeof (long) - 1] == 1);
  60 }], ac_cv_c_bigendian=no, ac_cv_c_bigendian=yes, ac_cv_c_bigendian=unknown)
  61 fi])
  62 if test $ac_cv_c_bigendian = unknown; then
  63   AC_MSG_WARN([Assuming little-endian target machine - this may be overriden by adding the line "ac_cv_c_bigendian=${ac_cv_c_bigendian='yes'}"
  64 to config.cache file])
  65 fi
  66 if test $ac_cv_c_bigendian = yes; then
  67   AC_DEFINE(WORDS_BIGENDIAN)
  68 fi
  69 ])
  70
  71 WX_C_BIGENDIAN
  72
  73
  74 dnl Checks for libraries.
  75 AC_CHECK_LIB(z, main, [ zlib="true" ], [ zlib="false" ;  AC_MSG_WARN([zlib missing. Will need zlib for PNG support])])
  76 AC_CHECK_LIB(m, main)
  77 AC_CHECK_LIB(curses, main, [curses=true], [curses=false])
  78 AC_CHECK_LIB(ncurses, main, [ncurses=true], [ncurses=false])
  79 AC_CHECK_LIB(g2, main, [g2=true], [g2=false])
  80 wxwin=false
  81 AC_CHECK_LIB(wx_gtk, main, [wxwin=true; wx_gtk=true; AC_DEFINE(HAVE_WXWINDOWS)])
  82 AC_CHECK_LIB(wx_msw, main, [wxwin=true; wx_msw=true; AC_DEFINE(HAVE_WXWINDOWS)])
  83 AC_CHECK_LIB(hdf5, main, [hdf5=true], [hdf5=false], -lz)
  84 AC_CHECK_LIB(fftw, main, [fftw=true; AC_DEFINE(HAVE_FFTW)], [fftw=false])
  85
  86 if test "$zlib" = "true" ; then
  87   AC_CHECK_LIB(png, main, [png=true ; AC_DEFINE(HAVE_PNG)], [png=false])
  88 fi
  89
  90 dnl Checks for header files.
  91 AC_HEADER_STDC
  92 AC_CHECK_HEADERS(fcntl.h unistd.h getopt.h sys/fcntl.h setjmp.h stdarg.h stddef.h sys/types.h sys/stat.h string.h ctype.h math.h stdio.h netinet/in.h inttypes.h sys/param.h stdint.h stdlib.h g2.h assert.h)
  93
  94 dnl Checks for typedefs, structures, and compiler characteristics.
  95 AC_C_CONST
  96 AC_TYPE_OFF_T
  97 AC_TYPE_SIZE_T
  98 AC_STRUCT_TM
  99
 100 dnl Checks for library functions.
 101 AC_FUNC_VPRINTF
 102 AC_CHECK_FUNCS(strtod strtol snprintf htonl)
 103 AC_CHECK_FUNC(basename)
 104 AC_CHECK_FUNC(setjmp)
 105 if test "${OSTYPE}" = "cygwin" ; then
 106   getopt_long=false
 107 else
 108   AC_CHECK_FUNC(getopt_long, [ getopt_long=true ], [ getopt_long=false ])
 109 fi
 110 if test "${getopt_long}" = "false" ; then
 111   my_includes="$myincludes -I../getopt"
 112   AC_DEFINE(HAVE_GETOPT_LONG)
 113   ctlibs_base="$ctlibs_base -lgetopt"
 114   LDFLAGS="$LDFLAGS -L../getopt"
 115   AM_CONDITIONAL(INCLUDED_GETOPT_LONG, test 1==1)
 116 fi
 117
 118 AC_ADD_GCC_CFLAGS([-Wall])
 119 AC_MSG_CHECKING(whether to enable verbose warnings)
 120 AC_ARG_ENABLE(verbose-warnings,
 121 [  --enable-verbose-warnings
 122                           Enable verbose compiler warnings.],
 123 [ case "$enableval" in
 124   yes)
 125     AC_MSG_RESULT(yes)
 126     AC_ADD_GCC_CFLAGS([-W])
 127     AC_ADD_GCC_CFLAGS([-Wshadow -Wpointer-arith -Wbad-function-cast])
 128     AC_ADD_GCC_CFLAGS([-Wcast-align -Wwrite-strings -Waggregate-return])
 129     AC_ADD_GCC_CFLAGS([-Wmissing-prototypes -Wstrict-prototypes])
 130     AC_ADD_GCC_CFLAGS([-pedantic])
 131     AC_ADD_GCC_CFLAGS([-Wredundant-decls])
 132
 133     ;;
 134   *)
 135     AC_MSG_RESULT(no)
 136     ;;
 137   esac ], AC_MSG_RESULT(no)
 138 )
 139
 140 dnl Check for debug mode
 141 AC_MSG_CHECKING([debug])
 142 AC_ARG_ENABLE(debug,
 143 [  --enable-debug          Turn on debugging],
 144 [case "${enableval}" in
 145   yes) debug=true
 146        AC_MSG_RESULT(yes)
 147        ;;
 148   no)  debug=false
 149        AC_MSG_RESULT(no)
 150        ;;
 151   *) AC_MSG_RESULT([bad value ${enableval} for --enable-debug])
 152        ;;
 153 esac],
 154 [debug=false; AC_MSG_RESULT(no)])
 155 AM_CONDITIONAL(DEBUG, test "$debug" = "true")
 156
 157 if test "$debug" = "true" ; then
 158   AC_ADD_GCC_CFLAGS([-g -DDEBUG])
 159   AC_DEFINE(DEBUG)
 160 else
 161   AC_ADD_GCC_CFLAGS([-g -O3 -DNDEBUG --fast-math])
 162   AC_DEFINE(NDEBUG)
 163 fi
 164
 165 dnl Set LAM path
 166 AC_ARG_WITH(lam,
 167 [  --with-lam[=PATH]       Set path of LAM MPI ],
 168 [    if test "$withval" != "no" ; then
 169          trylamdir=$withval
 170      fi ]
 171 )
 172
 173 if test "$withval" != "no" ; then
 174   if test "$prefix" != "NONE" ; then
 175      trylamdir="$trylamdir $prefix"
 176   fi
 177
 178   AC_MSG_CHECKING([for LAM MPI installation])
 179   for testlamdir in "." $trylamdir /usr/local /usr/local/lam /usr /usr/lam /opt /opt/lam ; do
 180     if test -x "$testlamdir/bin/hcc" ; then
 181       LDFLAGS="$LDFLAGS -L$testlamdir/lib"
 182       CFLAGS="$CFLAGS -I$testlamdir/include"
 183       lamdir="$testlamdir"
 184       AC_SUBST(lamdir)
 185       mpienable="true"
 186       AC_SUBST(mpienable)
 187       break
 188     fi
 189   done
 190   AC_MSG_RESULT($lamdir)
 191 else
 192   AC_MSG_RESULT([no])
 193 fi
 194
 195 AC_MSG_CHECKING([for web access])
 196 dnl Set cgi-bin directory
 197 AC_ARG_WITH(cgibin-dir, [  --with-cgibin-dir=PATH  Set path of CGI binaries directory ],
 198 [ cgibindir=$withval ; AC_SUBST(cgibindir) ] )
 199
 200 AC_ARG_WITH(cgibin-url, [  --with-cgibin-url=PATH  Set URL path of CGI binaries ],
 201 [ cgibinurl=$withval ; AC_SUBST(cgibinurl) ] )
 202
 203 AC_ARG_WITH(webdata-dir, [  --with-webdata-dir=PATH Set path of webdata],
 204 [ webdatadir=$withval ; AC_SUBST(webdatadir)  ] )
 205
 206 AC_ARG_WITH(webdata-url, [  --with-webdata-url=PATH Set URL path of webdata],
 207 [ webdataurl=$withval ; AC_SUBST(webdataurl) ] )
 208
 209 AC_ARG_WITH(html-dir, [  --with-html-dir=PATH    Set directory of html files],
 210 [ htmldir=$withval ; AC_SUBST(htmldir) ] )
 211
 212 if test -n "$cgibindir" -o -n "$cgibinurl" ; then
 213   cgiprograms="ctsim.cgi ctsim.conf"
 214   AC_SUBST(cgiprograms)
 215 fi
 216
 217 if test -n "$htmldir" ; then
 218   htmldata=simulate.html
 219   AC_SUBST(htmldata)
 220 fi
 221 AM_CONDITIONAL(USE_HTML, test -n "$htmldir")
 222
 223 if test -n "$cgibindir" -o -n "$cgibinurl" -o -n "$webdatadir" -o -n "$webdataurl" -o -n "$htmldir" ; then
 224   webenabled=true
 225   AC_SUBST(webenabled)
 226   AC_MSG_RESULT([yes])
 227   if test -z "$cgibindir" ; then
 228     AC_MSG_ERROR([--with-cgibin-dir not set for web access])
 229   elif test -z "$cgibinurl" ; then
 230     AC_MSG_ERROR([--with-cgibin-url not set for web access])
 231   elif test -z "$webdatadir" ; then
 232     AC_MSG_ERROR([--with-webdata-dir not set for web access])
 233   elif test -z "$webdataurl" ; then
 234     AC_MSG_ERROR([--with-webdata-url not set for web access])
 235   elif test -z "$htmldir" ; then
 236     AC_MSG_ERROR([--with-html-dir not set for web access])
 237   fi
 238 else
 239   AC_MSG_RESULT([no])
 240 fi
 241
 242 AM_CONDITIONAL(USE_LAM, test -n "$lamdir")
 243
 244 dnl Prepare to support X.  If the user gave the command-line option
 245 dnl --without-x, AC_PATH_XTRA will set no_x to "yes".  Otherwise, it will
 246 dnl add appropriate preprocessor flags to X_CFLAGS, and appropriate linker
 247 dnl flags to X_LIBS.  It also checks for system-specific X libraries, and
 248 dnl adds them to X_PRE_LIBS or X_EXTRA_LIBS, as appropriate.  (The former
 249 dnl is where "-lSM -lICE" goes, in X11R6.)  We define the X_TOOLKIT_LIBS
 250 dnl and X_BASIC_LIBS argument vectors ourselves, and if X is to be
 251 dnl supported, we'll concatenate the whole lot of these into a command line
 252 dnl for libtool.  See, e.g., the libplot_la_LIBADD line in
 253 dnl libplot/Makefile.am.
 254
 255 AC_PATH_XTRA
 256 AC_SUBST(X_CFLAGS)
 257 dnl Following five are concatenated together into a linker specification.
 258 AC_SUBST(X_LIBS)
 259 AC_SUBST(X_TOOLKIT_LIBS)
 260 AC_SUBST(X_PRE_LIBS)
 261 AC_SUBST(X_BASIC_LIBS)
 262 AC_SUBST(X_EXTRA_LIBS)
 263
 264 X_TOOLKIT_LIBS="-lXt"
 265 X_BASIC_LIBS="-lXext -lX11"
 266
 267 dnl Check whether libXt has thread support.  Some platforms may have
 268 dnl pthread support in libc, but no thread support in libXt/libX11.
 269 our_saved_LDFLAGS="$LDFLAGS"
 270 LDFLAGS="$X_LIBS $LDFLAGS"
 271 AC_CHECK_LIB(Xt, XtToolkitThreadInitialize, AC_DEFINE(X_THREAD_SUPPORT), , $X_PRE_LIBS $X_BASIC_LIBS $X_EXTRA_LIBS)
 272 LDFLAGS="$our_saved_LDFLAGS"
 273
 274 dnl Check in -lXext for double buffering extensions to X11, and check
 275 dnl whether appropriate header files are present.  (Some systems have one
 276 dnl but not the other.)
 277 our_saved_LDFLAGS="$LDFLAGS"
 278 LDFLAGS="$X_LIBS $LDFLAGS"
 279 AC_CHECK_LIB(Xext, XdbeQueryExtension, AC_DEFINE(HAVE_DBE_SUPPORT), , -lX11 "$X_EXTRA_LIBS")
 280 AC_CHECK_LIB(Xext, XmbufQueryExtension, AC_DEFINE(HAVE_MBX_SUPPORT), , -lX11 "$X_EXTRA_LIBS")
 281 LDFLAGS="$our_saved_LDFLAGS"
 282 our_saved_CPPFLAGS="$CPPFLAGS"
 283 CPPFLAGS="$X_CFLAGS $CPPFLAGS"
 284 AC_CHECK_HEADERS(X11/extensions/Xdbe.h X11/extensions/multibuf.h)
 285 CPPFLAGS="$our_saved_CPPFLAGS"
 286
 287 dnl Our Makefile.am files test the automake variable NO_X to determine
 288 dnl whether X should be supported.
 289 AM_CONDITIONAL(NO_X, test "x$no_x" = "xyes")
 290
 291 my_includes="$my_includes -I../include -I.."
 292 AC_SUBST(my_includes)
 293
 294 AC_MSG_CHECKING([interactive graphics])
 295 if test "$no_x" != "yes" ; then
 296   AC_DEFINE(HAVE_X11)
 297   AC_DEFINE(HAVE_SGP)
 298   AM_CONDITIONAL(HAVE_SGP, test 1==1)
 299   LDFLAGS="$LDFLAGS -L../libctgraphics -L/usr/X11R6/lib"
 300   ctlibs_graphics="$ctlibs_base -lctgraphics $X_BASIC_LIBS $X_TOOLKIT_LIBS"
 301   AC_MSG_RESULT(yes)
 302 else
 303   AC_MSG_RESULT(no)
 304 fi
 305
 306 if test "$png" = "true" ; then
 307   ctlibs_tools="$ctlibs_tools -lpng"
 308 fi
 309 if test "$zlib" = "true" ; then
 310   ctlibs_tools="$ctlibs_tools -lz"
 311 fi
 312 if test "$g2" = "true" ; then
 313   ctlibs_tools="$ctlibs_tools -lg2"
 314 fi
 315
 316 if test "$fftw" = "true" ; then
 317   ctlibs_tools="$ctlibs_tools -lrfftw -lfftw"
 318 fi
 319
 320 dnl Check for dmalloc
 321 AC_CHECK_LIB(dmallocxx, main, [dmallocxx=true], [dmallocxx=false])
 322 AC_MSG_CHECKING([for enable-dmalloc])
 323 AC_ARG_ENABLE(dmalloc,
 324 [  --enable-dmalloc        Use dmalloc memory allocation],
 325 [case "${enableval}" in
 326   yes) usedmalloc=true
 327        AC_MSG_RESULT(yes)
 328        ;;
 329   no)  usedmalloc=false
 330        AC_MSG_RESULT(no)
 331        ;;
 332   *) AC_MSG_RESULT([bad value ${enableval} for --enable-dmalloc])
 333        ;;
 334 esac],
 335 [usedmalloc=false; AC_MSG_RESULT(no)])
 336
 337 if test "$dmallocxx" = "true" -a "$usedmalloc" = "true" ; then
 338   ctlibs_tools="$ctlibs_tools -ldmallocxx"
 339   AC_DEFINE(HAVE_DMALLOC)
 340   AC_MSG_RESULT(Using dmalloc)
 341 fi
 342
 343 dnl Setting projet libraries and includes
 344 LDFLAGS="$LDFLAGS -L../libctsupport -L../libctsim"
 345 ctlibs="$ctlibs_base -lctsim $ctlibs_graphics -lctsupport $ctlibs_tools"
 346 AC_SUBST(ctlibs)
 347
 348 if test "$wxwin" = "true" ; then
 349   wxcflags=`$wxconfig --cflags`
 350   CFLAGS="$CFLAGS -I../include $wxcflags"
 351   wxlibs=`$wxconfig --libs`
 352   wxlibs="$wxlibs $ctlibs"
 353   AM_CONDITIONAL(HAVE_WXWINDOWS, test 1==1 )
 354 fi
 355 AC_SUBST(wxcflags)
 356 AC_SUBST(wxlibs)
 357
 358 if test -n "$lamdir" ; then
 359   lamprograms="pjrec-lam phm2if-lam phm2pj-lam"
 360   AC_SUBST(lamprograms)
 361 fi
 362
 363 CXXFLAGS="$CFLAGS"
 364
 365 AC_OUTPUT(Makefile libctgraphics/Makefile libctsupport/Makefile libctsim/Makefile Makefile man/Makefile doc/Makefile cgi-bin/ctsim.cgi cgi-bin/Makefile html/simulate.html html/Makefile include/Makefile getopt/Makefile tools/sample-ctsim.sh cgi-bin/ctsim.conf tools/Makefile src/Makefile)