dnl Process this file with autoconf to produce a configure script.

dnl Must reset CDPATH so that bash's cd does not print to stdout
dnl CDPATH=

AC_INIT(src/ctrec.c)
AM_INIT_AUTOMAKE(ctsim,0.5.2-b2)
AM_CONFIG_HEADER(config.h)

dnl Checks for programs.
AC_PROG_AWK
AC_PROG_INSTALL
AC_PROG_MAKE_SET
AC_PROG_RANLIB
AC_PROG_CC

dnl Checks for libraries.
AC_CHECK_LIB(z, main, 
[
  zlib="true"
],
[ 
  zlib="false"
  AC_MSG_WARN([zlib missing. Will need zlib for PNG support])
])
AC_CHECK_LIB(m, main)
AC_CHECK_LIB(curses, main, [curses=true], [curses=false])
AC_CHECK_LIB(ncurses, main, [ncurses=true], [ncurses=false])
 
dnl Checks for header files.
AC_HEADER_STDC
AC_CHECK_HEADERS(fcntl.h unistd.h getopt.h sys/fcntl.h setjmp.h stdarg.h stddef.h sys/types.h sys/stat.h string.h ctype.h math.h stdio.h)

dnl Checks for typedefs, structures, and compiler characteristics.
AC_C_CONST
AC_TYPE_OFF_T
AC_TYPE_SIZE_T
AC_STRUCT_TM

dnl Checks for library functions.
AC_FUNC_VPRINTF
AC_CHECK_FUNCS(strtod strtol)
AC_CHECK_FUNC(basename)
AC_CHECK_FUNC(setjmp)
AC_CHECK_FUNC(getopt_long,
[
  getopt_long=true
],
[
  getopt_long=false
  my_includes="$myincludes -I../getopt"
  AC_DEFINE(HAVE_GETOPT_LONG)
  ctlibs_base="$ctlibs_base -lgetopt"
  LDFLAGS="$LDFLAGS -L../getopt"
  AM_CONDITIONAL(INCLUDED_GETOPT_LONG, test 1==1)
])


AC_ADD_GCC_CFLAGS([-Wall])
AC_MSG_CHECKING(whether to enable verbose warnings)
AC_ARG_ENABLE(verbose-warnings,
[  --enable-verbose-warnings
                          Enable verbose compiler warnings.],
[ case "$enableval" in
  yes)
    AC_MSG_RESULT(yes)
    AC_ADD_GCC_CFLAGS([-W])
    AC_ADD_GCC_CFLAGS([-Wshadow -Wpointer-arith -Wbad-function-cast])
    AC_ADD_GCC_CFLAGS([-Wcast-align -Wwrite-strings -Waggregate-return])
    AC_ADD_GCC_CFLAGS([-Wmissing-prototypes -Wstrict-prototypes])
    AC_ADD_GCC_CFLAGS([-pedantic])
    AC_ADD_GCC_CFLAGS([-Wredundant-decls])

    ;;
  *)
    AC_MSG_RESULT(no)
    ;;
  esac ], AC_MSG_RESULT(no)
)

dnl Check for debug mode
AC_ARG_ENABLE(debug,
[  --enable-debug          Turn on debugging],
[case "${enableval}" in
  yes) debug=true ;;
  no)  debug=false ;;
  *) AC_MSG_ERROR(bad value ${enableval} for --enable-debug) ;;
esac],[debug=false])
AM_CONDITIONAL(DEBUG, test "$debug" = "true")

dnl Set PNG directory     
AC_MSG_CHECKING([for PNG library installation])
AC_ARG_WITH(png,
[  --with-png[=PATH]       Set path of lib PNG installation ],
[
     if test "$withval" != "no" ; then
         trypngdir=$withval
         if test "$prefix" != "NONE" ; then
         trypngdir="$trypngdir $prefix"
       fi
     fi
]
)

if test "$withval" != "no" -a "$zlib" = "true" ; then
  for testpngdir in "." $trypngdir /usr/local /usr /opt ; do
    if test -f "$testpngdir/lib/libpng.a" ; then
      if test ! -f "$testpngdir/include/png.h" ; then
        AC_MSG_ERROR([PNG library found, but png.h not found. Check PNG installation])
      else
          grep PNG_LIBPNG_VER_STRING "$testpngdir/include/png.h" | grep 9 > /dev/null 
          if test "$?" = "0" ; then
            AC_MSG_ERROR([Your version of libpng in $testpngdir is too old -- please upgrade])
          fi
      fi
      LDFLAGS="$LDFLAGS -L$testpngdir/lib"
      CFLAGS="$CFLAGS -I$testpngdir/include"
      pngdir="$testpngdir"
      AC_DEFINE(HAVE_PNG)
      break
    elif test -f "$testpngdir/libpng.a" ; then
      if test ! -f "$testpngdir/png.h" ; then
        AC_MSG_ERROR([PNG library found, but png.h not found. Check PNG installation])
      else
          grep PNG_LIBPNG_VER_STRING "$testpngdir/png.h" | grep 9 > /dev/null 
          if test "$?" = "0" ; then
            AC_MSG_ERROR([Your version of libpng in $testpngdir is too old -- please upgrade])
          fi
      fi
      LDFLAGS="$LDFLAGS -L$testpngdir"
      CFLAGS="$CFLAGS -I$testpngdir"
      pngdir="$testpngdir"
      AC_DEFINE(HAVE_PNG)
      break
    fi
  done
  AC_MSG_RESULT($pngdir)
  AM_CONDITIONAL(HAVE_PNG, test -n "$pngdir")
else
  AC_MSG_RESULT([no])
fi

dnl Set LAM path
AC_ARG_WITH(lam,
[  --with-lam[=PATH]       Set path of LAM MPI ],
[    if test "$withval" != "no" ; then
         trylamdir=$withval
     fi ]
)

if test "$withval" != "no" ; then
  if test "$prefix" != "NONE" ; then
     trylamdir="$trylamdir $prefix"
  fi

  AC_MSG_CHECKING([for LAM MPI installation])
  for testlamdir in "." $trylamdir /usr/local /usr/local/lam /usr /usr/lam /opt /opt/lam ; do
    if test -x "$testlamdir/bin/hcc" ; then
      LDFLAGS="$LDFLAGS -L$testlamdir/lib"
      CFLAGS="$CFLAGS -I$testlamdir/include"
      lamdir="$testlamdir"
      AC_SUBST(lamdir)
      mpienable="true"
      AC_SUBST(mpienable)
      break
    fi
  done
  AC_MSG_RESULT($lamdir)
fi

AC_MSG_CHECKING([for web access])
dnl Set cgi-bin directory
AC_ARG_WITH(cgibin-dir, [  --with-cgibin-dir=PATH  Set path of CGI binaries directory ], 
[ cgibindir=$withval ; AC_SUBST(cgibindir) ] )

AC_ARG_WITH(cgibin-url, [  --with-cgibin-url=PATH  Set URL path of CGI binaries ], 
[ cgibinurl=$withval ; AC_SUBST(cgibinurl) ] )

AC_ARG_WITH(webdata-dir, [  --with-webdata-dir=PATH Set path of webdata], 
[ webdatadir=$withval ; AC_SUBST(webdatadir)  ] )

AC_ARG_WITH(webdata-url, [  --with-webdata-url=PATH Set URL path of webdata], 
[ webdataurl=$withval ; AC_SUBST(webdataurl) ] )

AC_ARG_WITH(html-dir, [  --with-html-dir=PATH    Set directory of html files], 
[ htmldir=$withval ; AC_SUBST(htmldir) ] )

if test -n "$cgibindir" -o -n "$cgibinurl" ; then
  cgiprograms="ctsim.cgi ctsim.conf"
  AC_SUBST(cgiprograms)
fi

if test -n "$htmldir" ; then
  htmldata=ctsim.html
  AC_SUBST(htmldata)
fi
AM_CONDITIONAL(USE_HTML, test -n "$htmldir")

if test -n "$cgibindir" -o -n "$cgibinurl" -o -n "$webdatadir" -o -n "$webdataurl" -o -n "$htmldir" ; then
  webenabled=true
  AC_SUBST(webenabled)
  AC_MSG_RESULT([yes])
  if test -z "$cgibindir" ; then
    AC_MSG_ERROR([--with-cgibin-dir not set for web access])
  elif test -z "$cgibinurl" ; then
    AC_MSG_ERROR([--with-cgibin-url not set for web access])
  elif test -z "$webdatadir" ; then
    AC_MSG_ERROR([--with-webdata-dir not set for web access])
  elif test -z "$webdataurl" ; then
    AC_MSG_ERROR([--with-webdata-url not set for web access])
  elif test -z "$htmldir" ; then
    AC_MSG_ERROR([--with-html-dir not set for web access])
  fi
else
  AC_MSG_RESULT([no])
fi

AM_CONDITIONAL(USE_LAM, test -n "$lamdir")

dnl Prepare to support X.  If the user gave the command-line option
dnl --without-x, AC_PATH_XTRA will set no_x to "yes".  Otherwise, it will
dnl add appropriate preprocessor flags to X_CFLAGS, and appropriate linker
dnl flags to X_LIBS.  It also checks for system-specific X libraries, and
dnl adds them to X_PRE_LIBS or X_EXTRA_LIBS, as appropriate.  (The former
dnl is where "-lSM -lICE" goes, in X11R6.)  We define the X_TOOLKIT_LIBS
dnl and X_BASIC_LIBS argument vectors ourselves, and if X is to be
dnl supported, we'll concatenate the whole lot of these into a command line
dnl for libtool.  See, e.g., the libplot_la_LIBADD line in
dnl libplot/Makefile.am.

AC_PATH_XTRA
AC_SUBST(X_CFLAGS)
dnl Following five are concatenated together into a linker specification.
AC_SUBST(X_LIBS)
AC_SUBST(X_TOOLKIT_LIBS)
AC_SUBST(X_PRE_LIBS)
AC_SUBST(X_BASIC_LIBS)
AC_SUBST(X_EXTRA_LIBS)

X_TOOLKIT_LIBS="-lXt"
X_BASIC_LIBS="-lXext -lX11"

dnl Check whether libXt has thread support.  Some platforms may have
dnl pthread support in libc, but no thread support in libXt/libX11.
our_saved_LDFLAGS="$LDFLAGS"
LDFLAGS="$X_LIBS $LDFLAGS"
AC_CHECK_LIB(Xt, XtToolkitThreadInitialize, AC_DEFINE(X_THREAD_SUPPORT), , $X_PRE_LIBS $X_BASIC_LIBS $X_EXTRA_LIBS)
LDFLAGS="$our_saved_LDFLAGS"

dnl Check in -lXext for double buffering extensions to X11, and check
dnl whether appropriate header files are present.  (Some systems have one
dnl but not the other.)
our_saved_LDFLAGS="$LDFLAGS"
LDFLAGS="$X_LIBS $LDFLAGS"
AC_CHECK_LIB(Xext, XdbeQueryExtension, AC_DEFINE(HAVE_DBE_SUPPORT), , -lX11 "$X_EXTRA_LIBS")
AC_CHECK_LIB(Xext, XmbufQueryExtension, AC_DEFINE(HAVE_MBX_SUPPORT), , -lX11 "$X_EXTRA_LIBS")
LDFLAGS="$our_saved_LDFLAGS"
our_saved_CPPFLAGS="$CPPFLAGS"
CPPFLAGS="$X_CFLAGS $CPPFLAGS"
AC_CHECK_HEADERS(X11/extensions/Xdbe.h X11/extensions/multibuf.h)
CPPFLAGS="$our_saved_CPPFLAGS"

dnl Our Makefile.am files test the automake variable NO_X to determine
dnl whether X should be supported.
AM_CONDITIONAL(NO_X, test "x$no_x" = "xyes")

my_includes="$my_includes -I../include -I.."
AC_SUBST(my_includes)

if test "x$no_x" != "xyes" ; then
  AC_DEFINE(HAVE_INTERACTIVE_GRAPHICS)
  AM_CONDITIONAL(HAVE_INTERACTIVE_GRAPHICS, test 1==1)
  LDFLAGS="$LDFLAGS -L../libezplot -L../libgraph"
  ctlibs_base="$ctlibs_base -lezplot -lgraph"
fi

dnl Setting projet libraries and includes
LDFLAGS="$LDFLAGS -L../libkmath -L../libk -L../libcio -L../libir" 
ctlibs_base="$ctlibs_base -lkmath -lk -lcio"
if test -n "$pngdir" ; then
  ctlibs_base="$ctlibs_base -lpng"
fi
if test "$zlib" = "true" ; then
  ctlibs_base="$ctlibs_base -lz"
fi
ctlibs="-lir $ctlibs_base"

AC_SUBST(ctlibs)

if test -n "$lamdir" ; then
  ctlamlibs="-lir_lam $ctlibs_base"
  lamprograms="ctrec-lam phm2sdf-lam phm2rs-lam"
  AC_SUBST(lamprograms)
  AC_SUBST(ctlamlibs)
fi

AC_OUTPUT(Makefile libezplot/Makefile src/Makefile libgraph/Makefile libkmath/Makefile Makefile libk/Makefile libir/Makefile libcio/Makefile man/Makefile cgi-bin/ctsim.cgi cgi-bin/Makefile html/ctsim.html html/Makefile include/Makefile getopt/Makefile src/sample-ctrec.sh cgi-bin/ctsim.conf)