dnl Process this file with autoconf to produce a configure script.

dnl Must reset CDPATH so that bash's cd does not print to stdout
dnl CDPATH=

AC_INIT(src/ctsim.cpp)
AM_INIT_AUTOMAKE(ctsim,2.5.0)
AM_CONFIG_HEADER(config.h)

dnl Checks for programs.
AC_PROG_AWK
AC_PROG_INSTALL
AC_PROG_MAKE_SET
AC_PROG_RANLIB

CFLAGS="$CFLAGS -I/usr/local/include"
LDFLAGS="$LDFLAGS -L/usr/local/lib"
AC_PROG_CC
AC_PROG_CXX
AC_C_BIGENDIAN

AC_PATH_PROG(wxconfig,wx-config)

dnl AC_MSG_CHECKING([that the compiler works])
dnl AC_TRY_RUN([ main(int ac, char **av) { return 0; } ],     AC_MSG_RESULT(yes),     AC_MSG_RESULT(no)     AC_MSG_ERROR(Could not compile and run even a trivial ANSI C program - check CC.),     AC_MSG_ERROR(Could not compile and run even a trivial ANSI C program - check CC.))

dnl Check for C operation
AC_CANONICAL_HOST 
AC_C_INLINE
AC_CHECK_SIZEOF(short, 2)
AC_CHECK_SIZEOF(int, 4)
AC_CHECK_SIZEOF(long, 4)
AC_CHECK_SIZEOF(float, 4)
AC_CHECK_SIZEOF(double, 8)

dnl Checks for libraries.
AC_CHECK_LIB(z, deflate, [ zlib="true" ], [ zlib="false" ;  AC_MSG_WARN([zlib missing. Will need zlib for PNG support])])
AC_CHECK_LIB(m, sin)
AC_CHECK_LIB(curses, main, [curses=true], [curses=false])
AC_CHECK_LIB(ncurses, main, [ncurses=true], [ncurses=false])
AC_CHECK_LIB(g2, main, [g2=true], [g2=false])
wxwin=false
AC_CHECK_LIB(wx_gtk, main, [wxwin=true; wx_gtk=true; AC_DEFINE(HAVE_WXWINDOWS)])
AC_CHECK_LIB(wx, main, [wxwin=true; wx_msw=true; AC_DEFINE(HAVE_WXWINDOWS)])
AC_CHECK_LIB(hdf5, main, [hdf5=true], [hdf5=false], -lz)
AC_CHECK_LIB(fftw, fftw_one, [fftw=true; AC_DEFINE(HAVE_FFTW)], [fftw=false])

if test "$zlib" = "true" ; then
  AC_CHECK_LIB(png, main, [png=true ; AC_DEFINE(HAVE_PNG)], [png=false])
fi

dnl Checks for header files.
AC_HEADER_STDC
AC_CHECK_HEADERS(fcntl.h unistd.h getopt.h sys/fcntl.h setjmp.h stdarg.h stddef.h sys/types.h sys/stat.h string.h ctype.h math.h stdio.h netinet/in.h inttypes.h sys/param.h stdint.h stdlib.h g2.h assert.h sys/time.h sys/resource.h sys/time.h)

dnl Checks for typedefs, structures, and compiler characteristics.
AC_C_CONST
AC_TYPE_OFF_T
AC_TYPE_SIZE_T
AC_STRUCT_TM

dnl Checks for library functions.
AC_FUNC_VPRINTF
AC_CHECK_FUNCS(strtod strtol snprintf htonl usleep vsprintf vsnprintf)
AC_CHECK_FUNC(basename)
AC_CHECK_FUNC(setjmp)
AC_CHECK_FUNC(setpriority)
AC_CHECK_FUNC(time)
AC_CHECK_FUNC(gettimeofday)

if test "${OSTYPE}" = "cygwin" ; then
  getopt_long=false
else
  AC_CHECK_FUNC(getopt_long, [ getopt_long=true ], [ getopt_long=false ])
fi

if test "${getopt_long}" = "false" ; then
  my_includes="$my_includes -I../getopt"
  AC_DEFINE(HAVE_GETOPT_LONG)
  ctlibs_base="$ctlibs_base -lgetopt"
  LDFLAGS="$LDFLAGS -L../getopt"
  AM_CONDITIONAL(INCLUDED_GETOPT_LONG, test 1==1)
fi

dnl Check for debug mode
AC_MSG_CHECKING([debug])
AC_ARG_ENABLE(debug,
[  --enable-debug          Turn on debugging],
[case "${enableval}" in
  yes) debug=true 
       AC_MSG_RESULT(yes)
       ;;
  no)  debug=false 
       AC_MSG_RESULT(no)
       ;;
  *) AC_MSG_RESULT([bad value ${enableval} for --enable-debug]) 
       ;;
esac],
[debug=false; AC_MSG_RESULT(no)])
AM_CONDITIONAL(DEBUG, test "$debug" = "true")

if test "$debug" = "true" ; then
dnl  AC_ADD_GCC_CFLAGS([-g -DDEBUG])
  CFLAGS="-g -DDEBUG"
  AC_DEFINE(DEBUG)
else
dnl  AC_ADD_GCC_CFLAGS([-g -O2 -DNDEBUG])
  CFLAGS="-g -O3 -DNDEBUG"
  AC_DEFINE(NDEBUG)
fi

AC_MSG_CHECKING(sstream)
 if [ test -f /usr/include/sstream || test -f /usr/include/g++/sstream ||
     test -f /usr/include/g++-2/sstream || test -f /usr/include/g++-3/sstream ]; then
  AC_DEFINE(HAVE_SSTREAM)
  AC_MSG_RESULT(yes)
fi
AC_MSG_RESULT(no)


AC_ADD_GCC_CFLAGS([-Wall])
AC_MSG_CHECKING(whether to enable verbose warnings)
AC_ARG_ENABLE(verbose-warnings,
[  --enable-verbose-warnings
                          Enable verbose compiler warnings.],
[ case "$enableval" in
  yes)
    AC_MSG_RESULT(yes)
    AC_ADD_GCC_CFLAGS([-W])
    AC_ADD_GCC_CFLAGS([-Wshadow -Wpointer-arith -Wbad-function-cast])
    AC_ADD_GCC_CFLAGS([-Wcast-align -Wwrite-strings -Waggregate-return])
    AC_ADD_GCC_CFLAGS([-Wmissing-prototypes -Wstrict-prototypes])
    AC_ADD_GCC_CFLAGS([-pedantic])
    AC_ADD_GCC_CFLAGS([-Wredundant-decls])

    ;;
  *)
    AC_MSG_RESULT(no)
    ;;
  esac ], AC_MSG_RESULT(no)
)

AC_MSG_CHECKING(static executables)
AC_ARG_ENABLE(static,
[  --enable-static
                          Enable static executables.],
[ case "$enableval" in
  yes)
    AC_MSG_RESULT(yes)
    AC_ADD_GCC_CFLAGS([--static])
    ;;
  *)
    AC_MSG_RESULT(no)
    ;;
  esac ], AC_MSG_RESULT(no)
)

dnl Set LAM path
AC_ARG_WITH(lam,
[  --with-lam[=PATH]       Set path of LAM MPI ],
[    if test "$withval" != "no" ; then
         trylamdir=$withval
     fi ]
)

if test "$withval" != "no" ; then
  if test "$prefix" != "NONE" ; then
     trylamdir="$trylamdir $prefix"
  fi

  AC_MSG_CHECKING([for LAM MPI installation])
  for testlamdir in "." $trylamdir /usr/local /usr/local/lam /usr /usr/lam /opt /opt/lam ; do
    if test -x "$testlamdir/bin/hcp" ; then
      if test "$testlamdir" != "/usr"; then 	
        LDFLAGS="$LDFLAGS -L$testlamdir/lib"
        CFLAGS="$CFLAGS -I$testlamdir/include"
      fi
      CFLAGS="$CFLAGS -I$testlamdir/include/mpi2c++"
      lamdir="$testlamdir"
      AC_SUBST(lamdir)
      mpienable="true"
      AC_SUBST(mpienable)
      break
    fi
  done
  AC_MSG_RESULT($lamdir)
else
  AC_MSG_RESULT([no])
fi

AC_MSG_CHECKING([for web access])
dnl Set cgi-bin directory
AC_ARG_WITH(cgibin-dir, [  --with-cgibin-dir=PATH  Set path of CGI binaries directory ], 
[ cgibindir=$withval ; AC_SUBST(cgibindir) ] )

AC_ARG_WITH(cgibin-url, [  --with-cgibin-url=PATH  Set URL path of CGI binaries ], 
[ cgibinurl=$withval ; AC_SUBST(cgibinurl) ] )

AC_ARG_WITH(webdata-dir, [  --with-webdata-dir=PATH Set path of webdata], 
[ webdatadir=$withval ; AC_SUBST(webdatadir)  ] )

AC_ARG_WITH(webdata-url, [  --with-webdata-url=PATH Set URL path of webdata], 
[ webdataurl=$withval ; AC_SUBST(webdataurl) ] )

AC_ARG_WITH(html-dir, [  --with-html-dir=PATH    Set directory of html files], 
[ htmldir=$withval ; AC_SUBST(htmldir) ] )

if test -n "$cgibindir" -o -n "$cgibinurl" ; then
  cgiprograms="ctsim.cgi ctsim.conf"
  AC_SUBST(cgiprograms)
fi

if test -n "$htmldir" ; then
  htmldata=simulate.html
  AC_SUBST(htmldata)
fi
AM_CONDITIONAL(USE_HTML, test -n "$htmldir")

if test -n "$cgibindir" -o -n "$cgibinurl" -o -n "$webdatadir" -o -n "$webdataurl" -o -n "$htmldir" ; then
  webenabled=true
  AC_SUBST(webenabled)
  AC_MSG_RESULT([yes])
  if test -z "$cgibindir" ; then
    AC_MSG_ERROR([--with-cgibin-dir not set for web access])
  elif test -z "$cgibinurl" ; then
    AC_MSG_ERROR([--with-cgibin-url not set for web access])
  elif test -z "$webdatadir" ; then
    AC_MSG_ERROR([--with-webdata-dir not set for web access])
  elif test -z "$webdataurl" ; then
    AC_MSG_ERROR([--with-webdata-url not set for web access])
  elif test -z "$htmldir" ; then
    AC_MSG_ERROR([--with-html-dir not set for web access])
  fi
else
  AC_MSG_RESULT([no])
fi

AM_CONDITIONAL(USE_LAM, test -n "$lamdir")

dnl Prepare to support X.  If the user gave the command-line option
dnl --without-x, AC_PATH_XTRA will set no_x to "yes".  Otherwise, it will
dnl add appropriate preprocessor flags to X_CFLAGS, and appropriate linker
dnl flags to X_LIBS.  It also checks for system-specific X libraries, and
dnl adds them to X_PRE_LIBS or X_EXTRA_LIBS, as appropriate.  (The former
dnl is where "-lSM -lICE" goes, in X11R6.)  We define the X_TOOLKIT_LIBS
dnl and X_BASIC_LIBS argument vectors ourselves, and if X is to be
dnl supported, we'll concatenate the whole lot of these into a command line
dnl for libtool.  See, e.g., the libplot_la_LIBADD line in
dnl libplot/Makefile.am.

AC_PATH_XTRA
AC_SUBST(X_CFLAGS)
dnl Following five are concatenated together into a linker specification.
AC_SUBST(X_LIBS)
AC_SUBST(X_TOOLKIT_LIBS)
AC_SUBST(X_PRE_LIBS)
AC_SUBST(X_BASIC_LIBS)
AC_SUBST(X_EXTRA_LIBS)

X_TOOLKIT_LIBS="-lXt"
X_BASIC_LIBS="-lXext -lX11"

dnl Check whether libXt has thread support.  Some platforms may have
dnl pthread support in libc, but no thread support in libXt/libX11.
our_saved_LDFLAGS="$LDFLAGS"
LDFLAGS="$X_LIBS $LDFLAGS"
AC_CHECK_LIB(Xt, XtToolkitThreadInitialize, AC_DEFINE(X_THREAD_SUPPORT), , $X_PRE_LIBS $X_BASIC_LIBS $X_EXTRA_LIBS)
LDFLAGS="$our_saved_LDFLAGS"

dnl Check in -lXext for double buffering extensions to X11, and check
dnl whether appropriate header files are present.  (Some systems have one
dnl but not the other.)
our_saved_LDFLAGS="$LDFLAGS"
LDFLAGS="$X_LIBS $LDFLAGS"
AC_CHECK_LIB(Xext, XdbeQueryExtension, AC_DEFINE(HAVE_DBE_SUPPORT), , -lX11 "$X_EXTRA_LIBS")
AC_CHECK_LIB(Xext, XmbufQueryExtension, AC_DEFINE(HAVE_MBX_SUPPORT), , -lX11 "$X_EXTRA_LIBS")
LDFLAGS="$our_saved_LDFLAGS"
our_saved_CPPFLAGS="$CPPFLAGS"
CPPFLAGS="$X_CFLAGS $CPPFLAGS"
AC_CHECK_HEADERS(X11/extensions/Xdbe.h X11/extensions/multibuf.h)
CPPFLAGS="$our_saved_CPPFLAGS"

dnl Our Makefile.am files test the automake variable NO_X to determine
dnl whether X should be supported.
AM_CONDITIONAL(NO_X, test "x$no_x" = "xyes")

my_includes="$my_includes -I../include -I.. -I/usr/local/include"
AC_SUBST(my_includes)

LDFLAGS="$LDFLAGS -L/usr/local/lib"

AC_MSG_CHECKING([for X])
if test "$no_x" != "yes" ; then
  AC_DEFINE(HAVE_SGP)
  AM_CONDITIONAL(HAVE_SGP, test 1==1)
  AC_DEFINE(HAVE_X11)
  LDFLAGS="$LDFLAGS -L../libctgraphics -L/usr/X11R6/lib"
  ctlibs_graphics="$ctlibs_base -lctgraphics"
  AC_MSG_RESULT(yes)
  if test "$g2" = "true" ; then
  ctlibs_graphics="$ctlibs_graphics -lg2"
  AC_DEFINE(HAVE_G2)
  fi	
  ctlibs_graphics="$ctlibs_graphics $X_BASIC_LIBS $X_TOOLKIT_LIBS"
else
  if test "$wxwin" = "true" ; then
    AC_DEFINE(HAVE_SGP)
    AM_CONDITIONAL(HAVE_SGP, test 1==1)
  fi
  AC_MSG_RESULT(no)
fi

if test "$png" = "true" ; then
  ctlibs_tools="$ctlibs_tools -lpng"
fi
if test "$zlib" = "true" ; then
  ctlibs_tools="$ctlibs_tools -lz"
fi
if test "$fftw" = "true" ; then
  ctlibs_tools="$ctlibs_tools -lrfftw -lfftw"
fi

dnl Check for dmalloc
AC_CHECK_LIB(dmallocxx, main, [dmallocxx=true], [dmallocxx=false])
AC_MSG_CHECKING([for enable-dmalloc])
AC_ARG_ENABLE(dmalloc,
[  --enable-dmalloc        Use dmalloc memory allocation],
[case "${enableval}" in
  yes) usedmalloc=true 
       AC_MSG_RESULT(yes)
       ;;
  no)  usedmalloc=false 
       AC_MSG_RESULT(no)
       ;;
  *) AC_MSG_RESULT([bad value ${enableval} for --enable-dmalloc]) 
       ;;
esac],
[usedmalloc=false; AC_MSG_RESULT(no)])

if test "$dmallocxx" = "true" -a "$usedmalloc" = "true" ; then
  ctlibs_tools="$ctlibs_tools -ldmallocxx"
  AC_DEFINE(HAVE_DMALLOC)
  AC_MSG_RESULT(Using dmalloc)
fi

if test "$wxwin" = "true" ; then
  if test "$wx_gtk" = "true" ; then	
    wxcflags=`$wxconfig --cflags`
    wxlibs=`$wxconfig --libs`
  else
	wxcflags="-D__WXMSW__ -D__WIN32__ -D__GNUWIN32__"
   wxlibs="-lwx -lglui -ljpeg -lxpm -lzlib -ltiff"
  fi
  CFLAGS="$CFLAGS -I../include $wxcflags"
  ctlibs_graphics="$ctlibs_graphics $wxlibs"
  AM_CONDITIONAL(HAVE_WXWINDOWS, test 1==1 )
fi
AC_SUBST(wxcflags)
AC_SUBST(wxlibs)

dnl Setting projet libraries and includes
LDFLAGS="$LDFLAGS -L../libctsupport -L../libctsim" 
ctlibs="$ctlibs_base -lctsim $ctlibs_graphics -lctsupport $ctlibs_tools"
AC_SUBST(ctlibs)

if test -n "$lamdir" ; then
  lamprograms="pjrec-lam phm2if-lam phm2pj-lam"
  AC_SUBST(lamprograms)
  lamdefs="$CFLAGS"
  AC_SUBST(lamdefs)
fi

CXXFLAGS="$CFLAGS"

AC_OUTPUT(Makefile libctgraphics/Makefile libctsupport/Makefile libctsim/Makefile Makefile man/Makefile doc/Makefile cgi-bin/ctsim.cgi cgi-bin/Makefile html/simulate.html html/Makefile include/Makefile getopt/Makefile tools/sample-ctsim.sh cgi-bin/ctsim.conf tools/Makefile src/Makefile)